ruby-websocket-extensions/trunk/PKGBUILD

   1 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   2
   3 _gemname='websocket-extensions'
   4 pkgname="ruby-${_gemname}"
   5 pkgver=0.1.5
   6 pkgrel=2
   7 pkgdesc='Generic extension manager for WebSocket connections'
   8 arch=('any')
   9 url='https://github.com/faye/websocket-extensions-ruby'
  10 license=('Apache')
  11 options=(!emptydirs)
  12 depends=('ruby')
  13 checkdepends=('ruby-bundler' 'ruby-rspec')
  14 source=("${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
  15 sha512sums=('a80154d0c83743ffa4dd3eee1adcc93bb38907fbae4260602a91c922e5a022806413a8aa84dc10bc14b5ed2ca928765ef4c39e04ff0a0c5f9b423aff2b2514fd')
  16
  17 prepare() {
  18   cd "${_gemname}-ruby-${pkgver}"
  19
  20   # update gemspec/Gemfile to allow newer version of the dependencies
  21   sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
  22 }
  23
  24 build() {
  25   cd "${_gemname}-ruby-${pkgver}"
  26
  27   gem build "${_gemname}.gemspec"
  28 }
  29
  30 check() {
  31   cd "${_gemname}-ruby-${pkgver}"
  32
  33   bundle exec rspec
  34 }
  35
  36 package() {
  37   cd "${_gemname}-ruby-${pkgver}"
  38
  39   local _gemdir="$(gem env gemdir)"
  40
  41   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"
  42
  43   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  44
  45   install -Dm 644 CHANGELOG.md CODE_OF_CONDUCT.md README.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
  46 }