rustypaste-cli/trunk/PKGBUILD

   1 # Maintainer: Leonidas Spyropoulos <artafinde@archlinux.org>
   2 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   3
   4 pkgname='rustypaste-cli'
   5 pkgdesc="A CLI tool for rustypaste"
   6 pkgver=0.3.0
   7 pkgrel=1
   8 arch=('x86_64')
   9 url="https://github.com/orhun/rustypaste-cli"
  10 license=('MIT')
  11 depends=('gcc-libs')
  12 makedepends=('cargo')
  13 provides=('rpaste')
  14 source=(${pkgname}-${pkgver}.tar.gz::"${url}/archive/v${pkgver}.tar.gz")
  15 sha256sums=('691fd3ddcf2c7c9c17728a304bd4299a35812940902b8b31059902abb49b037e')
  16
  17 prepare() {
  18   cd "${pkgname}-${pkgver}"
  19   cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
  20 }
  21
  22 build(){
  23   cd "${pkgname}-${pkgver}"
  24   CFLAGS+=' -ffat-lto-objects'
  25   env CARGO_INCREMENTAL=0 cargo build --release --frozen
  26 }
  27
  28 check(){
  29   cd "${pkgname}-${pkgver}"
  30   env CARGO_INCREMENTAL=0 cargo test --frozen
  31 }
  32
  33 package() {
  34   cd "${pkgname}-${pkgver}"
  35   install -D -m755 "target/release/rpaste" "${pkgdir}/usr/bin/rpaste"
  36   install -D -m644 "config.toml" "${pkgdir}/usr/share/doc/rustypaste-cli/example/config.toml"
  37   install -D -m644 "man/rpaste.1" -t "${pkgdir}/usr/share/man/man1"
  38   install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  39   install -D -m644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
  40 }
  41
  42 # vim:set ts=2 sw=2 et: