sad/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Joost Bremmer <contact at madeofmagicandwires dot online>
   4 # Contributor: Eliezio Oliveira <eliezio@pm.me>
   5 # Contributor: Matthew Gamble <internet@matthewgamble.net>
   6
   7 pkgname=sad
   8 pkgver=0.4.22
   9 pkgrel=1
  10 pkgdesc='Space Age seD'
  11 arch=('x86_64')
  12 url='https://github.com/ms-jpq/sad'
  13 license=('MIT')
  14 depends=('gcc-libs')
  15 makedepends=('git' 'rust')
  16 optdepends=(
  17   'fzf: for tui usage'
  18   'diff-so-fancy: for diff colourizer'
  19   'git-delta: for diff colourizer'
  20 )
  21 options=('!lto')
  22 _commit='3d709fc2d8c1f504e92378c46f19360b91c65828'
  23 source=("$pkgname::git+$url#commit=$_commit")
  24 b2sums=('SKIP')
  25
  26 pkgver() {
  27   cd "$pkgname"
  28
  29   git describe --tags | sed 's/^v//'
  30 }
  31
  32 prepare() {
  33   cd "$pkgname"
  34
  35   # download dependencies
  36   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  37 }
  38
  39 build() {
  40   cd "$pkgname"
  41   cargo build --frozen --release --all-features
  42 }
  43
  44 check() {
  45   cd "$pkgname"
  46   cargo test --frozen --all-features
  47 }
  48
  49 package() {
  50   cd "$pkgname"
  51
  52   # binary
  53   install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
  54
  55   # license
  56   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  57
  58   # documentation
  59   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  60 }
  61
  62 # vim: set ts=2 sts=2 sw=2 et :