sequoia-keyring-linter/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgname=sequoia-keyring-linter
   4 pkgver=1.0.0
   5 pkgrel=1
   6 pkgdesc='OpenPGP certificate linter'
   7 url='https://sequoia-pgp.org/'
   8 arch=('x86_64')
   9 license=('GPL2')
  10 groups=('sequoia')
  11 depends=('glibc' 'nettle' 'libhogweed.so' 'libnettle.so' 'gcc-libs' 'gmp')
  12 makedepends=('git' 'cargo' 'llvm' 'clang')
  13 source=(https://gitlab.com/sequoia-pgp/keyring-linter/-/archive/v${pkgver}/keyring-linter-v${pkgver}.tar.gz)
  14 sha512sums=('64623a175d84d124e0943f74d06b28d9f0182d14cb1f28bd52511816d86ef280854591115dd8e94abe4d01072b8e2b363015aa8fba5c1dccc086c0dfd284c6fe')
  15 b2sums=('0f495bfa8772274a0c39d0b8fe000bd08223fea7434ce4edfaed73dbf3c38209cab457c501f14f4e538d09b8f9ad4a1156ea1b7c95c74dec1b63902455862417')
  16
  17 prepare() {
  18   cd keyring-linter-v${pkgver}
  19   sed 's/debug/release/g' -i -- Makefile
  20 }
  21
  22 build() {
  23   cd keyring-linter-v${pkgver}
  24   cargo build --release
  25   make
  26 }
  27
  28 check() {
  29   cd keyring-linter-v${pkgver}
  30   cargo test --release
  31 }
  32
  33 package() {
  34   cd keyring-linter-v${pkgver}
  35   install -Dm 755 target/release/sq-keyring-linter -t "${pkgdir}/usr/bin"
  36   install -Dm 644 sq-keyring-linter.1 -t "${pkgdir}/usr/share/man/man1"
  37   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  38 }
  39
  40 # vim: ts=2 sw=2 et: