singularity/repos/community-any/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
   2 # Contributor: Lone_Wolf <lonewolf@xs4all.nl>
   3 # Contributor: sausageandeggs <s_stoakley at hotmail.co.uk>
   4
   5 pkgname=singularity
   6 pkgver=1.00
   7 pkgrel=6
   8 pkgdesc="Endgame: Singularity - simulation of true AI"
   9 arch=('any')
  10 url="http://emhsoft.com/singularity/index.html"
  11 license=('GPL2' 'custom')
  12 depends=('python' 'python-pygame' 'python-numpy')
  13 makedepends=('python-setuptools')
  14 source=("https://github.com/singularity/singularity/releases/download/v${pkgver}/singularity-${pkgver}.tar.gz"{,.asc}
  15         https://github.com/singularity/singularity-music/archive/025e2696638bcc3bf7690679c3a17c0b46823bbe.tar.gz
  16         "singularity.desktop")
  17 validpgpkeys=('B3131A451DBFDF7CA05B4197054BBB9F7D806442')
  18 sha512sums=('f3581048c5a535fdbd28d2af1ac596f5396fd712b716931f17de75f8b170f0e226deb2c113023357e21e7de1294e4a632515962df9ee43768baf0fb4bbaa08da'
  19             'SKIP'
  20             '9ec095e8882aa3981a4bbfe551f8d61c876fc6d0ee082f558f8e0f3015bfb65d23d76e5c3557a3e9ab41ddfe896eff618934c043ce8cee58709548f02fa81625'
  21             'd37e1a2a6d8e832a81114133df0ea5d5aeb531c81ba606b6bd49a6a38db1825660de9248593b9bfb40ddab4e1c9f794b6b5ed11ea273adb8bd9b4a363896b135')
  22
  23 prepare() {
  24   cd "$pkgname-$pkgver"
  25
  26   mv "$srcdir"/singularity-music-* singularity/music
  27   sed -i "s|prune|recursive-include singularity/music *|g" MANIFEST.in
  28   sed -i "s|replaceme|python$(pacman -Q python | cut -d ' ' -f 2 | cut -d . -f 1,2)|g" "$srcdir"/singularity.desktop
  29 }
  30
  31 build() {
  32   cd "$pkgname-$pkgver"
  33
  34   python setup.py build
  35 }
  36
  37 package() {
  38   cd "$pkgname-$pkgver"
  39
  40   python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  41   mv run_singularity.sh "$pkgdir"/usr/bin/singularity
  42
  43   install -Dm644 "$srcdir/singularity.desktop" "$pkgdir/usr/share/applications/singularity.desktop"
  44   install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE.cc0.txt LICENSE.CC-BY-SA-3.txt LICENSE.gpl.txt LICENSE.txt
  45 }
  46 # vim: sw=2:ts=2 et: