skim/repos/community-x86_64/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   3 # Contributor: fenuks
   4
   5 pkgname=skim
   6 pkgver=0.10.4
   7 pkgrel=1
   8 pkgdesc='Fuzzy Finder in Rust!'
   9 arch=('x86_64')
  10 url='https://github.com/lotabout/skim'
  11 license=('MIT')
  12 depends=('ncurses')
  13 makedepends=('git' 'rust')
  14 optdepends=(
  15   'bash: for resp. completions and key bindings, and for sk-tmux script'
  16   'fish: for resp. key bindings'
  17   'tmux: for sk-tmux script'
  18   'vim-plugin-runtime: for N/Vim plugin'
  19   'zsh: for resp. completions and key bindings'
  20 )
  21 _commit='db9f194c12486343ae23b37781123ff0dbfaaf16'
  22 source=("$pkgname::git+$url#commit=$_commit")
  23 b2sums=('SKIP')
  24
  25 pkgver() {
  26   cd "$pkgname"
  27
  28   git describe --tags | sed 's/^v//'
  29 }
  30
  31 prepare() {
  32   cd "$pkgname"
  33
  34   # download dependencies
  35   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  36 }
  37
  38 build() {
  39   cd "$pkgname"
  40
  41   cargo build --frozen --release --all-features
  42 }
  43
  44 check() {
  45   cd "$pkgname"
  46
  47   cargo test --frozen --all-features
  48 }
  49
  50 package() {
  51   cd "$pkgname"
  52
  53   # binary
  54   install -vDm755 -t "$pkgdir/usr/bin" target/release/sk bin/sk-tmux
  55
  56   # man pages
  57   install -vDm644 -t "$pkgdir/usr/share/man/man1" man/man1/*
  58
  59   # vim plugin
  60   install -vDm644 -t "$pkgdir/usr/share/vim/vimfiles/plugin" plugin/skim.vim
  61
  62   # key bindings
  63   install -vDm644 -t "$pkgdir/usr/share/skim" shell/*.bash shell/*.zsh
  64   install -vDm644 shell/key-bindings.fish "$pkgdir/usr/share/fish/functions/skim_key_bindings.fish"
  65
  66   # license
  67   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  68 }
  69
  70 # vim:set ts=2 sw=2 et: