spire/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Christian Rebischke <chris.rebischke@archlinux.org>
   2
   3 pkgbase=spire
   4 pkgname=("spire-agent" "spire-server")
   5 pkgver=1.6.3
   6 pkgrel=1
   7 pkgdesc="SPIFFE Runtime Environment"
   8 url='https://github.com/spiffe/spire'
   9 arch=("x86_64")
  10 license=("Apache")
  11 makedepends=("go")
  12 depends=("glibc")
  13 source=("${pkgbase}-${pkgver}.tar.gz::https://github.com/spiffe/spire/archive/v${pkgver}.tar.gz")
  14 sha512sums=('68140c66fd2410a299b637f6fbac1573756c505baa9bad6f685f5a729fbfdd0efc18db4c1e9569c3d6cff36a4bd60337301543c7c76b76e89511df8e0db74e3c')
  15 b2sums=('514cefd45718479f68a429517bd347856437ab5419041ca5fa53eac579d1e42faa01847866cf36968ddaf753048bef5e8939ceb3a9f0032fcc83fe917f0c2012')
  16
  17 build() {
  18   cd "${pkgbase}-${pkgver}"
  19   export CGO_CPPFLAGS="${CPPFLAGS}"
  20   export CGO_CFLAGS="${CFLAGS}"
  21   export CGO_CXXFLAGS="${CXXFLAGS}"
  22   export CGO_LDFLAGS="${LDFLAGS}"
  23   export GOFLAGS="-buildmode=pie -ldflags=-linkmode=external -trimpath -mod=readonly -modcacherw"
  24   cd cmd/spire-agent/
  25   go build -o spire-agent .
  26   cd ../../cmd/spire-server
  27   go build -o spire-server .
  28 }
  29
  30 check() {
  31   cd "${pkgbase}-${pkgver}"
  32   # test is blocking for some reason..
  33   # go test -v ./...
  34 }
  35
  36 package_spire-agent() {
  37   pkgdesc="SPIFFE runtime environment (agent)"
  38   provides=("spire-agent")
  39   depends=("glibc")
  40   cd "${pkgbase}-${pkgver}"
  41   install -Dsm755 cmd/spire-agent/spire-agent "${pkgdir}/usr/bin/spire-agent"
  42 }
  43
  44 package_spire-server() {
  45   pkgdesc="SPIFFE runtime environment (server)"
  46   provides=("spire-server")
  47   depends=("glibc")
  48   cd "${pkgbase}-${pkgver}"
  49   install -Dsm755 cmd/spire-server/spire-server "${pkgdir}/usr/bin/spire-server"
  50 }