stow/repos/community-any/PKGBUILD

   1 # Maintainer: Brett Cornwall <ainola@archlinux.org>
   2 # Contributor: Sébastien Luttringer
   3 # Contributor: eric
   4 # Contributor: Tom Newsom
   5 # Contributor: Chris Brannon
   6
   7 pkgname=stow
   8 pkgver=2.3.1
   9 pkgrel=3
  10 pkgdesc='Manage installation of multiple softwares in the same directory tree'
  11 url='https://www.gnu.org/software/stow/'
  12 arch=('any')
  13 license=('GPL3')
  14 depends=('perl')
  15 checkdepends=('perl-test-output' 'perl-io-stringy')
  16 validpgpkeys=('942B9075ACCA04E9037C73FED31B5563DAC1D4FA')  # Adam Spiers
  17 source=("https://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig})
  18 sha256sums=('09d5d99671b78537fd9b2c0b39a5e9761a7a0e979f6fdb7eabfa58ee45f03d4b'
  19             'SKIP')
  20
  21 build() {
  22     cd "$pkgname-$pkgver"
  23     ./configure \
  24         --prefix=/usr \
  25         --mandir=/usr/share/man \
  26         --infodir=/usr/share/info \
  27         --with-pmdir=/usr/share/perl5/vendor_perl
  28     make
  29 }
  30
  31 check() {
  32     cd "$pkgname-$pkgver"
  33     make check
  34 }
  35
  36 package() {
  37     cd "$pkgname-$pkgver"
  38     make DESTDIR="$pkgdir" install
  39 }