tang/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 pkgname=tang
   3 pkgver=11
   4 _commit=e2059ee1109510a7c14b099af7dcd8631e598270 # git rev-parse "v$pkgver^{}"
   5 pkgrel=2
   6 pkgdesc='Server for binding data to network presence'
   7 arch=('x86_64')
   8 url='https://github.com/latchset/tang'
   9 license=('GPL3')
  10 depends=('http-parser' 'jose')
  11 makedepends=('git' 'asciidoc' 'meson')
  12 checkdepends=('systemd')
  13 source=("git+$url.git?signed#commit=$_commit"
  14         'tang.sysusers.conf'
  15         'tang.tmpfiles.conf')
  16 sha512sums=('SKIP'
  17             '08b5abb5ff5195a96c1196e7336eefeabad36a82ef8862881689e3c9cfa8aebc5679e14c4aacc3fa80793fe42ffa591e6ec0ec07bf98f6e0d783e23b2f06218a'
  18             '48c3026b37ce3fe180633facb99a194e1fcb0ff860f6dff33541b6216b441572c1de0620102ce25e36c06f3c769b3149cb595f5aa4e355416c680b1c6f73e957')
  19 validpgpkeys=('7CE2CB3D2AF59FE1EA22F551D0D219ED1F7E762C') # Sergio Correia <scorreia@redhat.com>
  20
  21 pkgver() {
  22         cd "$pkgname"
  23         git describe --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
  24 }
  25
  26 build() {
  27         cd "$pkgname"
  28         meson --libexecdir=/usr/lib --buildtype=plain build
  29         meson compile -C build
  30 }
  31
  32 check() {
  33         cd "$pkgname"
  34         meson test -C build
  35 }
  36
  37 package() {
  38         cd "$pkgname"
  39         DESTDIR="$pkgdir" meson install -C build
  40         mkdir -pm700 "$pkgdir/var/db/tang"
  41         install -Dm644 "$srcdir/tang.sysusers.conf" "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  42         install -Dm644 "$srcdir/tang.tmpfiles.conf" "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
  43 }