tcplay/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
   3 # Contributor: Thomas Weißschuh <thomas t-8ch de>
   4 # Contributor: James Reed <supplantr at archlinux dot info>
   5
   6 pkgname=tcplay
   7 pkgver=3.3
   8 pkgrel=2
   9 pkgdesc='Free and simple TrueCrypt implementation based on dm-crypt'
  10 url='https://github.com/bwalex/tc-play'
  11 arch=('x86_64')
  12 license=('BSD')
  13 depends=('glibc' 'device-mapper' 'util-linux-libs' 'libgcrypt' 'libuuid.so')
  14 makedepends=('cmake' 'udev')
  15 provides=('libtcplay.so')
  16 source=(https://github.com/bwalex/tc-play/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  17 sha256sums=('ad53cd814a23b4f61a1b2b6dc2539624ffb550504c400c45cbd8cd1da4c7d90a')
  18 b2sums=('c02489d6e291dfc1425745af86506e72fda7f67dba0668b9250a85604ba301761b5bbbad6927238042a0f89da1035d9e3275006e34e895835a53cdc24974f419')
  19
  20 build() {
  21   mkdir -p tc-play-${pkgver}/build
  22   cd tc-play-${pkgver}/build
  23   # cmake is stupid
  24   export CFLAGS+=" ${CPPFLAGS}"
  25   cmake \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DLIB_SUFFIX= \
  28     -DSBIN_DIR=bin ..
  29   make VERBOSE=1
  30 }
  31
  32 package() {
  33   cd tc-play-${pkgver}
  34   make -C build DESTDIR="$pkgdir" install
  35   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  36   install -Dm 644 CHANGELOG README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  37 }
  38
  39 # vim: ts=2 sw=2 et: