texworks/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 pkgname=texworks
   3 pkgver=0.6.8
   4 _tag=605a1c74393fb84acdf7dc9d8cf42d154d9de719 # git rev-parse "release-$pkgver"
   5 pkgrel=1
   6 pkgdesc='Unicode-based, TeX-aware editor with integrated PDF viewer'
   7 arch=('x86_64')
   8 url='https://www.tug.org/texworks/'
   9 license=('GPL')
  10 depends=('hunspell' 'libsynctex' 'poppler-qt5' 'qt5-base' 'qt5-declarative' 'qt5-script' 'libpoppler-qt5.so')
  11 makedepends=('git' 'cmake' 'lua' 'python' 'qt5-tools')
  12 checkdepends=('gsfonts' 'poppler-data' 'xorg-server-xvfb')
  13 optdepends=('gsfonts: correctly display PDF files without embedded fonts'
  14             'lua: Lua scripts support'
  15             'poppler-data: correctly display certain CJK documents'
  16             'python: Python scripts support'
  17             'texlive-core: typeset TeX documents')
  18 source=("git+https://github.com/TeXworks/texworks.git?signed#tag=$_tag")
  19 sha512sums=('SKIP')
  20 validpgpkeys=('8740ED04AF6A4FCC6BC51C426806F10000582F84'
  21               '21BC42D38D1B03BE59F7A8F15016D150EA64A3D9') # Stefan Löffler (TeXworks) <st.loeffler@gmail.com>
  22
  23 pkgver() {
  24         cd "$pkgname"
  25         git describe | sed 's/^release-//;s/\([^-]*-\)g/r\1/;s/-/./g'
  26 }
  27
  28 build() {
  29         cmake -B build \
  30               -S "$pkgname" \
  31               -DCMAKE_BUILD_TYPE=None \
  32               -DCMAKE_INSTALL_PREFIX=/usr \
  33               -DTW_BUILD_ID='Arch Linux' \
  34               -DWITH_PYTHON=ON
  35         cmake --build build
  36 }
  37
  38 check() {
  39         cd build
  40         xvfb-run ctest --output-on-failure
  41 }
  42
  43 package() {
  44         DESTDIR="$pkgdir" cmake --install build
  45 }