watchexec/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Vlad M. <vlad@archlinux.net>
   3
   4 pkgname=watchexec
   5 pkgver=1.22.3
   6 pkgrel=1
   7 pkgdesc="Executes commands in response to file modifications"
   8 url='https://github.com/watchexec/watchexec'
   9 depends=('gcc-libs' 'zlib')
  10 makedepends=('cargo')
  11 arch=('x86_64')
  12 license=('Apache')
  13 source=("$pkgname-$pkgver.tar.gz::https://github.com/watchexec/watchexec/archive/refs/tags/v${pkgver}.tar.gz")
  14 options=('!lto')
  15 sha256sums=('698ed1dc178279594542f325b23f321c888c9c12c1960fe11c0ca48ba6edad76')
  16
  17 build() {
  18   cd "watchexec-$pkgver"
  19   cargo build --release --locked
  20 }
  21
  22 check() {
  23   cd "watchexec-$pkgver"
  24   cargo test --locked
  25 }
  26
  27 package() {
  28   cd "watchexec-$pkgver"
  29   install -Dm644 "doc/watchexec.1" "$pkgdir/usr/share/man/man1/watchexec.1"
  30   gzip -9 "$pkgdir/usr/share/man/man1/watchexec.1"
  31   install -Dm644 "completions/zsh" "$pkgdir/usr/share/zsh/site-functions/_watchexec"
  32   install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
  33   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  34 }