widelands/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Arkham <arkham at archlinux dot us>
   3 # Contributor: Christoph Zeiler <rabyte*gmail>
   4
   5 pkgname=widelands
   6 pkgver=1.1
   7 epoch=1
   8 pkgrel=2
   9 pkgdesc="A realtime strategy game with emphasis on economy and transport"
  10 arch=('x86_64')
  11 url="https://widelands.org/"
  12 license=('GPL')
  13 depends=('sdl2_mixer' 'sdl2_image' 'sdl2_ttf' 'lua' 'glew' 'python' 'dbus' 'minizip')
  14 makedepends=('cmake' 'mesa' 'ninja' 'git' 'asio')
  15 replaces=('widelands-data')
  16 source=("$pkgname-$pkgver.tar.gz::https://github.com/widelands/widelands/archive/refs/tags/v${pkgver}.tar.gz")
  17 sha512sums=('29dbeae0940468c8aad6f0fa610c8467bdb6ecf2ba5fe9175683b7cdaab5f977fa86beb71de29057c829e9738568d15e10bc22fa7fc9e58132151a1a02d72d9d')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21
  22   cmake \
  23       -GNinja \
  24       -Bbuild \
  25       -DCMAKE_BUILD_TYPE=Release \
  26       -DCMAKE_INSTALL_PREFIX=/usr \
  27       -DWL_INSTALL_BINDIR=bin \
  28       -DWL_INSTALL_BASEDIR=/usr \
  29       -DWL_INSTALL_DATADIR=/usr/share/widelands
  30   ninja -C build
  31 }
  32
  33 package() {
  34   cd $pkgname-$pkgver
  35
  36   DESTDIR="$pkgdir" ninja -C build install
  37
  38   # Fix wrong locations of some installed files (upstream bug)
  39   # See also FS#72240
  40   mv "$pkgdir"/usr/{VERSION,ChangeLog,CREDITS} "$pkgdir"/usr/share/widelands
  41
  42   mkdir -p "$pkgdir"/usr/share/licenses/$pkgname
  43   mv "$pkgdir"/usr/COPYING "$pkgdir"/usr/share/licenses/$pkgname
  44
  45 }