wxsvg/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Leonidas Spyropoulos <artafinde at gmail com>
   3 # Contributor: Miguel Revilla <yo@miguelrevilla.com>
   4 # Contributor: Joshua Stiefer <facedelajunk@gmail.com>
   5 # Contributor: Alexander Fehr <pizzapunk gmail com>
   6 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   7
   8 pkgname=wxsvg
   9 pkgver=1.5.24
  10 pkgrel=2
  11 pkgdesc='C++ library to create, manipulate and render SVG files'
  12 arch=('x86_64')
  13 url='http://wxsvg.sourceforge.net/'
  14 license=('custom:wxWindows')
  15 depends=('ffmpeg' 'libexif' 'wxwidgets-gtk3')
  16 makedepends=('webkit2gtk')
  17 source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2")
  18 sha256sums=('ae473291f8d0a5feafa06cd270c826c6bead4bceb2b9dd6fcecf2db7c25e2482')
  19
  20 prepare() {
  21   cd $pkgname-$pkgver
  22   sed -i 's/libwxsvg_la_LDFLAGS = /libwxsvg_la_LDFLAGS = $(LDFLAGS) /' src/Makefile.am
  23   autoreconf -fi
  24 }
  25
  26 build() {
  27   cd $pkgname-$pkgver
  28   ./configure --prefix=/usr
  29   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  30   make
  31 }
  32
  33 package() {
  34   cd $pkgname-$pkgver
  35   make DESTDIR="$pkgdir" install
  36   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  37 }