ytfzf/repos/community-any/PKGBUILD

   1 # Maintainer: Brett Cornwall <ainola@archlinux.org>
   2 # Contributor: Gennadiy Mykhailiuta
   3 # Contributor: Westofer Raymond
   4
   5 pkgname=ytfzf
   6 pkgver=2.6.0
   7 pkgrel=1
   8 pkgdesc="A POSIX script to find and watch youtube videos from the terminal"
   9 arch=('any')
  10 url="https://github.com/pystardust/ytfzf"
  11 license=('GPL3')
  12 depends=('jq' 'curl')
  13 makedepends=('gzip')
  14 optdepends=(
  15     'dmenu: Search prompts and results via dmenu'
  16     'mpv: Default media player'
  17     'fzf: The default menu selection screen'
  18     'ueberzug: The default thumbnails image previewer'
  19     'yt-dlp: For downloading content'
  20 )
  21 source=("$pkgname-$pkgver.tar.gz::https://github.com/pystardust/ytfzf/archive/refs/tags/v$pkgver.tar.gz")
  22 sha256sums=('bc54847ec3d613e25902404cfcb8dfdc657c8258b7cefdeb581cc92d58696835')
  23
  24 package() {
  25     cd "$pkgname-$pkgver"
  26     install -Dm0755 ytfzf -t "$pkgdir/usr/bin/"
  27
  28     install -dm0755 "$pkgdir/usr/share/$pkgname/addons"
  29     cp -r addons/* "$pkgdir/usr/share/$pkgname/addons"
  30     find "$pkgdir/usr/share/$pkgname/addons" -exec chmod 0755 {} +
  31
  32     install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  33     cd docs
  34     install -dm0755 "$pkgdir"/usr/share/man/man{1,5}
  35     gzip < "man/$pkgname.1" > "$pkgdir/usr/share/man/man1/$pkgname.1.gz"
  36     gzip < "man/$pkgname.5" > "$pkgdir/usr/share/man/man5/$pkgname.5.gz"
  37     install -Dm0644 conf.sh -t "$pkgdir/usr/share/doc/$pkgname"
  38     install -Dm0644 subscriptions -t "$pkgdir/usr/share/doc/$pkgname"
  39 }