zellij/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
   3
   4 pkgname=zellij
   5 pkgver=0.36.0
   6 pkgrel=1
   7 pkgdesc="A terminal multiplexer"
   8 arch=('x86_64')
   9 url="https://zellij.dev"
  10 license=('MIT')
  11 depends=('gcc-libs')
  12 makedepends=('cargo' 'mandown')
  13 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/zellij-org/${pkgname}/archive/v${pkgver}.tar.gz")
  14 sha512sums=('a5271245fc51d7dbe5c311e5cb0a0437ca86160c0d26014580d1a21ab5d498586f6bb115af3bccd6f64aec2b1d30eb4df6aaf085214fc9f565a4c8f7bd1ce941')
  15 options=('!lto')
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   RUSTUP_TOOLCHAIN=stable cargo build --release --frozen
  25   ./target/release/zellij setup --generate-completion bash > target/zellij.bash
  26   ./target/release/zellij setup --generate-completion fish > target/zellij.fish
  27   ./target/release/zellij setup --generate-completion zsh > target/zellij.zsh
  28   mandown docs/MANPAGE.md > assets/zellij.1
  29 }
  30
  31 package() {
  32   cd "$pkgname-$pkgver"
  33   install -Dm755 target/release/zellij -t "${pkgdir}/usr/bin"
  34   install -Dm644 GOVERNANCE.md README.md -t "${pkgdir}/usr/share/doc/zellij"
  35   install -Dm644 LICENSE.md -t "${pkgdir}/usr/share/licenses/zellij"
  36   install -Dm644 target/zellij.bash "${pkgdir}/usr/share/bash-completion/completions/zellij"
  37   install -Dm644 target/zellij.fish "${pkgdir}/usr/share/fish/vendor_completions.d/zellij.fish"
  38   install -Dm644 target/zellij.zsh "${pkgdir}/usr/share/zsh/site-functions/_zellij"
  39   install -Dm644 assets/zellij.1 "${pkgdir}/usr/share/man/man1/zellij.1"
  40   install -Dm644 assets/zellij.desktop "${pkgdir}/usr/share/applications/zellij.desktop"
  41 }
  42
  43 # vim: ts=2 sw=2 et: