zim/trunk/PKGBUILD

   1 # Maintainer: Florian Pritz <bluewind@xinu.at>
   2 # Contributor: Kevin Piche <kevin@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4
   5 pkgname=zim
   6 pkgver=0.75.1
   7 pkgrel=2
   8 pkgdesc="A WYSIWYG text editor that aims at bringing the concept of a wiki to the desktop."
   9 arch=(any)
  10 license=('GPL' 'PerlArtistic')
  11 url="https://zim-wiki.org/"
  12 depends=('python' 'python-gobject' 'ttf-font' 'gtk3' 'python-xdg')
  13 checkdepends=('xorg-server-xvfb')
  14 optdepends=('bzr: Version Control plugin'
  15             'git: Version Control plugin'
  16             'mercurial: Version Control plugin'
  17             'gnuplot: Insert Gnuplot plugin'
  18             'ditaa: Insert Ditaa plugin'
  19             'graphviz: Insert Diagram plugin'
  20             'xdot: Link Map plugin'
  21             'gtkspell3: Spell Checker plugin'
  22             'r: Insert GNU R Plot plugin'
  23             'scrot: Insert Screenshot plugin'
  24             'lilypond: Insert Score plugin'
  25             'gtksourceview3: Source View plugin'
  26             'texlive-bin: Insert Equation plugin')
  27 source=("https://www.zim-wiki.org/downloads/${pkgname}-${pkgver}.tar.gz")
  28 sha256sums=('88e175d7f7e141896f9e958989d252d722556af17bc4bc6f065e7d54287d0385')
  29
  30 check() {
  31         cd "${srcdir}/${pkgname}-${pkgver}"
  32
  33         xvfb-run -w0 ./test.py
  34 }
  35
  36 package() {
  37         cd "${srcdir}/${pkgname}-${pkgver}"
  38
  39         python setup.py install --root="${pkgdir}" --optimize=1
  40
  41         install -dm755 "$pkgdir/usr/share/icons/"
  42         cp -r xdg/hicolor/ "$pkgdir/usr/share/icons/"
  43 }