zita-rev1/trunk/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 pkgname=zita-rev1
   3 pkgver=0.2.2
   4 pkgrel=2
   5 pkgdesc="A reworked jack version of the reverb originally developed for Aeolus."
   6 arch=('x86_64')
   7 url="https://kokkinizita.linuxaudio.org/linuxaudio/zita-rev1-doc/quickguide.html"
   8 license=('GPL2')
   9 groups=('pro-audio')
  10 depends=('cairo' 'clxclient' 'clthreads' 'jack')
  11 makedepends=('gendesk')
  12 source=("https://kokkinizita.linuxaudio.org/linuxaudio/downloads/${pkgname}-${pkgver}.tar.bz2")
  13 sha512sums=('7ba145da6eb3163c84c8efac59c2bff3973d215caa1e4ffc9d6b9bf4eab50cc57133a439bde216724edbb0268366891bc2ddb1950c46804debde7404ce171279')
  14
  15 prepare() {
  16   cd "${pkgname}-${pkgver}"
  17   # strip march=native
  18   sed -e '/native/d' \
  19       -i source/Makefile
  20   # XDG desktop files
  21   gendesk -n \
  22           --pkgname ${pkgname} \
  23           --pkgdesc "${pkgdesc}" \
  24           --name zita-rev1 \
  25           --categories "AudioVideo;Audio"
  26 }
  27
  28 build() {
  29   cd "${pkgname}-${pkgver}/source"
  30   make PREFIX=/usr
  31 }
  32
  33 package() {
  34   cd "${pkgname}-${pkgver}/source"
  35   make DESTDIR="${pkgdir}/" PREFIX=/usr install
  36   # XDG desktop integration
  37   install -vDm 644 "../${pkgname}.desktop" \
  38     -t "${pkgdir}/usr/share/applications/"
  39   # docs
  40   install -t "${pkgdir}/usr/share/doc/$pkgname" \
  41     -vDm 644 ../{AUTHORS,README,doc/*}
  42 }
  43 # vim:set ts=2 sw=2 et: