astroid/trunk/PKGBUILD

   1 # Maintainer: Daurnimator <daurnimator@archlinux.org>
   2 # Contributor: Gaute Hope <eg@gaute.vetsj.com>
   3 # Contributor: Johannes Heinz <heinzeljo@web.de>
   4 pkgname=astroid
   5 pkgver=0.16
   6 pkgrel=6
   7 pkgdesc="A graphical threads-with-tags style, lightweight and fast, e-mail client for Notmuch"
   8 arch=('x86_64')
   9 url="https://github.com/astroidmail/astroid"
  10 license=('GPL3')
  11 depends=('boost-libs'
  12          'gmime3'
  13          'gobject-introspection-runtime'
  14          'gtkmm3'
  15          'libpeas'
  16          'libsass'
  17          'notmuch'
  18          'protobuf'
  19          'vte3'
  20          'webkit2gtk')
  21 makedepends=('boost'
  22              'cmake'
  23              'cmark'
  24              'gobject-introspection'
  25              'ruby-ronn'
  26              'w3m')
  27 checkdepends=('notmuch-runtime'
  28               'xorg-server-xvfb')
  29 optdepends=('cmark: for markdown to html composition'
  30             'emacs: can be used as editor'
  31             'gvim: default editor')
  32 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/astroidmail/astroid/archive/v${pkgver}.tar.gz")
  33 sha256sums=('32ecb8c2fafe67f70c7d5f2bc60bda1796d98a56a75f7868c7c1ca50cd7baf5e')
  34
  35 build() {
  36   cd "${pkgname}-${pkgver}"
  37
  38   cmake -B build \
  39     -DCMAKE_BUILD_TYPE="None" \
  40     -DCMAKE_INSTALL_PREFIX="/usr" \
  41     -Wno-dev
  42   cmake --build build
  43 }
  44
  45 check() {
  46   cd "${pkgname}-${pkgver}"
  47
  48   cd build
  49   xvfb-run ctest --output-on-failure
  50 }
  51
  52 package() {
  53   cd "${pkgname}-${pkgver}"
  54
  55   DESTDIR="${pkgdir}" cmake --install build
  56 }