cadence/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
   3 # Contributor: falkTX <falktx at gmail dot com>
   4
   5 _name=Cadence
   6 pkgname=cadence
   7 pkgver=0.9.2
   8 pkgrel=2
   9 pkgdesc="JACK toolbox for audio production."
  10 arch=(x86_64)
  11 url="https://kx.studio/Applications:Cadence"
  12 license=(GPL2)
  13 depends=(
  14   alsa-utils # for aplay/ arecord calls
  15   bash
  16   gcc-libs
  17   glibc
  18   hicolor-icon-theme
  19   jack2-dbus
  20   python
  21   python-dbus
  22   python-pyqt5
  23   qt5-base
  24   qt5-svg
  25   sh
  26 )
  27 makedepends=(
  28   a2jmidid
  29   jack_capture
  30   libpulse
  31   pulseaudio-jack
  32   python-rdflib
  33   zita-ajbridge
  34 )
  35 optdepends=(
  36   'a2jmidid: ALSA to JACK MIDI bridge'
  37   'jack_capture: recording via Cadence-Render'
  38   'pulseaudio-jack: PulseAudio to JACK bridge'
  39   'python-rdflib: LADSPA-RDF support in Carla'
  40   'zita-ajbridge: ALSA to JACK bridge'
  41 )
  42 source=(https://github.com/falkTX/$pkgname/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)
  43 sha512sums=('d8a1b52c361e3e18a193d1c283bb69abe18ce667b554fc53cb9b752d92747269145144ae512895ffbb5df76efe8671cfc0782f29e59d0d7cd3d97c97240bdecf')
  44 b2sums=('a5422e4d74618e2e45d9c6f275393a6e918783fc37d60a54142725aa54e691435c41f76dd0346fae7684c452988b07a18d817902abd917dbceaff5fb4aaa6c47')
  45
  46 build() {
  47   make -C $_name-$pkgver
  48 }
  49
  50 package() {
  51   make DESTDIR="$pkgdir" PREFIX=/usr install -C $_name-$pkgver
  52   install -vDm 644 $_name-$pkgver/{README.md,TODO} -t "$pkgdir/usr/share/doc/$pkgname/"
  53
  54   # removing claudia, as its runtime dependency ladish (dead) depends on
  55   # flowcanvas (dead)
  56   rm -rfv "$pkgdir/usr/bin/claudia"* \
  57           "$pkgdir/usr/share/applications/claudia"* \
  58           "$pkgdir/usr/share/$pkgname/"{icons,src}/{,ui_}claudia* \
  59           "$pkgdir/usr/share/icons/hicolor/"{128x128,16x16,256x256,48x48,scalable}/apps/claudia*
  60 }