containerd/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Morten Linderud <foxboron@archlinux.org>
   2 # Maintainer: Santiago Torres-Arias <santiago@archlinux.org>
   3 # Contributor: Sébastien "Seblu" Luttringer
   4 # Contributor: Iwan Timmer <irtimmer@gmail.com>
   5
   6 pkgname=containerd
   7 pkgver=1.7.1
   8 pkgrel=1
   9 pkgdesc='An open and reliable container runtime'
  10 url='https://containerd.io/'
  11 depends=('runc')
  12 makedepends=('go' 'git' 'btrfs-progs' 'libseccomp' 'containers-common' 'go-md2man')
  13 provides=('container-runtime')
  14 arch=('x86_64' 'aarch64')
  15 license=("Apache")
  16 source=("git+https://github.com/containerd/containerd.git#tag=v${pkgver}?signed")
  17 validpgpkeys=("8C7A111C21105794B0E8A27BF58C5D0A4405ACDB") # Derek McGowan
  18 sha256sums=('SKIP')
  19
  20 prepare() {
  21   # fix paths in service
  22   sed -i 's,/sbin,/usr/bin,;s,/usr/local,/usr,' $pkgname/containerd.service
  23 }
  24
  25 build() {
  26   cd "${pkgname}"
  27   export GOFLAGS="-trimpath -mod=readonly -modcacherw"
  28   make VERSION=v$pkgver GO_BUILD_FLAGS="-trimpath -mod=readonly -modcacherw" GO_GCFLAGS="" EXTRA_LDFLAGS="-buildid="
  29   make VERSION=v$pkgver man
  30 }
  31
  32 check() {
  33   cd "${pkgname}"
  34   # Ugly, but they are trying to do priviledged operations during testing
  35   GOFLAGS="-trimpath" make test || true
  36 }
  37
  38 package() {
  39   cd "${pkgname}"
  40   make PREFIX=/usr DESTDIR="$pkgdir/" install
  41   install -Dm644 containerd.service "$pkgdir"/usr/lib/systemd/system/containerd.service
  42   install -Dm644 man/*.8 -t "$pkgdir/usr/share/man/man8"
  43   install -Dm644 man/*.5 -t "$pkgdir/usr/share/man/man5"
  44 }