kicad/repos/community-x86_64/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Filipe Laíns <lains@archlinux.org>
   3 # Contributor: Marq Schneider <queueRAM@gmail.com>
   4 # Contributor: Nick Østergaard
   5 # Contributor: Rachel Mant <aur@dragonmux.network>
   6 # Contributor: Kyle Keen <keenerd@gmail.com>
   7
   8 pkgname=kicad
   9 pkgver=7.0.3
  10 pkgrel=1
  11 pkgdesc='Electronic schematic and printed circuit board (PCB) design tools'
  12 arch=('x86_64')
  13 url='http://kicad.org/'
  14 license=('GPL')
  15 depends=(
  16   'boost-libs'
  17   'curl'
  18   'glew'
  19   'glm'
  20   'ngspice'
  21   'opencascade'
  22   'python'
  23   'python-wxpython'
  24   'wxwidgets-gtk3'
  25   'unixodbc'
  26 )
  27 makedepends=(
  28   'git'
  29   'cmake'
  30   'ninja'
  31   'mesa'
  32   'boost'
  33   'swig'
  34 )
  35 optdepends=(
  36   'kicad-library: for footprints, symbols and templates'
  37   'kicad-library-3d: for 3D models of components'
  38 )
  39 _commit='54253ba8a34ee569f627c55e7bfa081c0aed3542'
  40 source=(
  41   "$pkgname::git+https://gitlab.com/kicad/code/kicad.git#commit=$_commit"
  42   'fix-archive-permissions.patch'
  43   'fix-version-string.patch'
  44 )
  45 sha512sums=('SKIP'
  46             'e36912e4144c6debe33f1711ca7a2da020389a6e376282c70f534ce9e685d0b35b58d88b810327d8baeb3466e87eda246ebf181c18e134e80bc73b91dae4bf02'
  47             '17100967610c85ce2e8a860dcf703a87dc0c20f52d3f056cdb5d16323160e8594698bd51e095aea63c00a75ce8b121be681e93cec1bab72a8d1d4eb8065a91f5')
  48 b2sums=()
  49
  50 pkgver() {
  51   cd "$pkgname"
  52
  53   git describe --tags | sed 's/^v//'
  54 }
  55
  56 prepare() {
  57   cd "$pkgname"
  58
  59   patch -p1 -i "$srcdir/fix-archive-permissions.patch"
  60   patch -p1 -i "$srcdir/fix-version-string.patch"
  61 }
  62
  63 build() {
  64   cmake \
  65     -B build \
  66     -S "$pkgname" \
  67     -G Ninja \
  68     -D CMAKE_BUILD_TYPE=Release \
  69     -D CMAKE_INSTALL_PREFIX=/usr \
  70     -D KICAD_USE_OCE=ON \
  71     -D KICAD_USE_EGL=ON \
  72     -D KICAD_BUILD_I18N=ON \
  73     -D KICAD_I18N_UNIX_STRICT_PATH=ON \
  74     -D KICAD_BUILD_QA_TESTS=OFF \
  75     -W no-dev
  76
  77   cmake --build build
  78 }
  79
  80 package() {
  81   DESTDIR="$pkgdir" cmake --install build
  82
  83   strip "$STRIP_SHARED" "${pkgdir}"/usr/lib/python*/site-packages/_pcbnew.so
  84 }
  85
  86 # vim:set ts=2 sw=2 et: