lib32-libcanberra/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Florian Pritz <flo@xssn.at>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgname=lib32-libcanberra
   6 pkgver=0.30+r2+gc0620e4
   7 pkgrel=2
   8 epoch=1
   9 pkgdesc="A small and lightweight implementation of the XDG Sound Theme Specification (32-bit)"
  10 url="https://0pointer.net/lennart/projects/libcanberra/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(lib32-libvorbis lib32-libltdl lib32-alsa-lib lib32-libpulse lib32-tdb
  14          libcanberra)
  15 makedepends=(gtk-doc lib32-gtk2 lib32-gtk3 git)
  16 provides=(lib32-libcanberra-pulse libcanberra{,-gtk,-gtk3}.so)
  17 replaces=("lib32-libcanberra-pulse<0.30+2+gc0620e4-4")
  18 options=(libtool)
  19 _commit=c0620e432650e81062c1967cc669829dbd29b310  # master
  20 source=("git+https://git.0pointer.net/clone/libcanberra.git#commit=$_commit"
  21         libcanberra-multi-backend.patch)
  22 sha256sums=('SKIP'
  23             'de146cae3e40a16b38c8edb4f1a3a423c64eb9c5000e36c316b677e9909c9b06')
  24
  25 pkgver() {
  26   cd libcanberra
  27   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd libcanberra
  32
  33   # https://bugs.archlinux.org/task/71341
  34   # https://bugs.freedesktop.org/show_bug.cgi?id=51662
  35   git apply -3 ../libcanberra-multi-backend.patch
  36
  37   ./autogen.sh
  38 }
  39
  40 build() {
  41   cd libcanberra
  42
  43   export CC="gcc -m32"
  44   export CXX="g++ -m32"
  45   export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
  46
  47   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  48       --libdir=/usr/lib32 \
  49       --disable-static --with-builtin=dso --enable-null --disable-oss \
  50       --enable-alsa --enable-pulse \
  51       --with-systemdsystemunitdir=/usr/lib/systemd/system --enable-gtk-doc
  52   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  53   make
  54 }
  55
  56 package() {
  57   cd libcanberra
  58
  59   make -j1 DESTDIR="$pkgdir" install
  60
  61   rm "$pkgdir"/usr/lib32/*.la
  62   rm "$pkgdir"/usr/lib32/gtk-{2,3}.0/modules/*.la
  63
  64   rm -r "$pkgdir"/usr/{include,share,bin,lib,lib32/gnome-settings-daemon-3.0}
  65 }
  66
  67 # vim:set sw=2 sts=-1 et: