libwhereami/trunk/PKGBUILD

   1 # Maintainer: Thore Bödecker <foxxx0@archlinux.org>
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3 # Contributor: Tim Meusel <tim@bastelfreak.de>
   4
   5 pkgname=libwhereami
   6 pkgver=0.5.0
   7 pkgrel=16
   8 pkgdesc='Library to report hypervisor information from inside a VM'
   9 arch=('x86_64')
  10 url='https://github.com/puppetlabs/libwhereami'
  11 license=('APACHE')
  12 depends=('boost-libs' 'gcc-libs' 'glibc' 'leatherman' 'leatherman_execution.so'
  13          'leatherman_file_util.so' 'leatherman_util.so' 'leatherman_logging.so'
  14          'leatherman_locale.so')
  15 makedepends=('boost' 'cmake' 'rapidjson' 'curl')
  16 checkdepends=('python')
  17 provides=('libwhereami.so')
  18 source=("${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
  19 sha512sums=('e9a0332f4ec0a2e6201cdf6212f2f1ced5a948e94aaa638c8d8a69f7306828b6168924775788b31316eecab59377a5ebd9310293e8e708e418c68fe47b248c13')
  20
  21 build() {
  22   cd ${pkgname}-${pkgver}
  23   cmake \
  24     -B build \
  25     -DCMAKE_BUILD_TYPE=None \
  26     -DENABLE_CXX_WERROR=OFF \
  27     -DCMAKE_INSTALL_PREFIX:PATH=/usr \
  28     -DBUILD_SHARED_LIBS=ON
  29   make -C build
  30 }
  31
  32 check() {
  33   cd ${pkgname}-${pkgver}/build
  34   make test
  35 }
  36
  37 package() {
  38   cd ${pkgname}-${pkgver}
  39
  40   make -C build DESTDIR="${pkgdir}" install
  41   install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  42   install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  43 }
  44
  45 # vim: ts=2 sw=2 et: