meson-python/trunk/PKGBUILD

   1 # Maintainer:
   2
   3 pkgname=meson-python
   4 pkgver=0.13.1
   5 pkgrel=2
   6 pkgdesc='Meson PEP 517 Python build backend'
   7 arch=(any)
   8 url='https://github.com/mesonbuild/meson-python'
   9 license=(MIT)
  10 depends=(meson patchelf python-wheel python-pyproject-metadata)
  11 makedepends=(python-build python-installer ninja)
  12 checkdepends=(python-pytest python-gitpython python-pytest-mock cython)
  13 source=(https://github.com/mesonbuild/meson-python/archive/$pkgver/$pkgname-$pkgver.tar.gz)
  14 sha256sums=('1637fc6b69b0b3152f5998fa0a6acfb4733c6ec246ea1e811e75e9ba8a53a64c')
  15
  16 prepare() {
  17   cd $pkgname-$pkgver
  18   sed -e '/ninja/d' -i pyproject.toml
  19 }
  20
  21 build() {
  22   cd $pkgname-$pkgver
  23   python -m build --wheel --no-isolation
  24 }
  25
  26 check() {
  27   cd $pkgname-$pkgver
  28   python -m venv --system-site-packages test-env
  29   test-env/bin/python -m installer dist/*.whl
  30 # https://github.com/mesonbuild/meson-python/issues/397
  31   test-env/bin/python -m pytest -k 'not test_user_args'
  32 }
  33
  34 package() {
  35   cd $pkgname-$pkgver
  36   python -m installer --destdir="$pkgdir" dist/*.whl
  37   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  38 }