opensearch-security-plugin/trunk/PKGBUILD

   1 # Maintainer: Justin Kromlinger <hashworks@archlinux.org>
   2
   3 pkgname=opensearch-security-plugin
   4 pkgver=2.6.0.0
   5 pkgrel=1
   6 _opensearchver=2.6.0
   7 _jdkver=11
   8 pkgdesc="OpenSearch Security Plugin"
   9 arch=('x86_64')
  10 url="https://opensearch.org/docs/latest/security-plugin"
  11 license=('Apache')
  12 depends=("opensearch=${_opensearchver}")
  13 makedepends=("java-environment=${_jdkver}" 'unzip' 'git')
  14 source=("git+https://github.com/opensearch-project/security.git#tag=${pkgver}") # Build requires git
  15 sha256sums=('SKIP')
  16
  17 build() {
  18   cd "security"
  19   export JAVA_HOME="/usr/lib/jvm/java-${_jdkver}-openjdk"
  20   export PATH="/usr/lib/jvm/java-${_jdkver}-openjdk/bin:$PATH"
  21   export GRADLE_OPTS="-Dbuild.snapshot=false -Dopensearch.version=${_opensearchver}"
  22
  23   # Currently the tests don't provide a way to skip the integration tests
  24   # … so we skip them entirely for now
  25   ./gradlew assemble
  26 }
  27
  28 package() {
  29   install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-security"
  30   cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-security"
  31   unzip "${srcdir}/security/build/distributions/opensearch-security-${pkgver}.zip"
  32
  33   install -Dm644 "${srcdir}/security/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
  34 }