par2cmdline/trunk/PKGBUILD

   1 # vim:set ts=2 sw=2 et:
   2 # Maintainer: BlackEagle < ike DOT devolder AT gmail DOT com >
   3 # Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org
   4
   5 pkgname=par2cmdline
   6 pkgver=0.8.1
   7 pkgrel=2
   8 pkgdesc='A PAR 2.0 compatible file verification and repair tool'
   9 url='https://github.com/BlackIkeEagle/par2cmdline'
  10 license=('GPL2')
  11 arch=('x86_64')
  12 depends=('gcc-libs')
  13 source=("https://github.com/Parchive/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz"
  14         "https://github.com/Parchive/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz.sig")
  15 sha512sums=('b0032639353d869ffa449c8b5f27fe1deec0e5e4326ba90aae5c8a03f82441c69ba40f2032c4cbda98f415c3d100136beed8285d099ffbf32329451e719478d9'
  16             'SKIP')
  17
  18 validpgpkeys=(
  19   'DB2277BCD500AA3825610BDDDB323392796CA067'
  20 )
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   ./configure --prefix=/usr
  25   make
  26 }
  27
  28 check() {
  29   cd "$pkgname-$pkgver"
  30   make -j1 check
  31 }
  32
  33 package() {
  34   cd "$pkgname-$pkgver"
  35   make DESTDIR="$pkgdir" install
  36 }