penguin-subtitle-player/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Alex Wiggins <alex.d.wiggins at gmail . com>
   3
   4 pkgname=penguin-subtitle-player
   5 pkgver=1.5.0
   6 pkgrel=3
   7 pkgdesc='Standalone subtitle player'
   8 arch=('x86_64')
   9 url='https://github.com/carsonip/Penguin-Subtitle-Player'
  10 license=('GPL3')
  11 depends=('hicolor-icon-theme' 'qt5-base')
  12 makedepends=('git')
  13 _commit=ca6a87e7ec3fe4ab0925525bfa771700022c5697  # tags/v1.5.0
  14 source=("git+https://github.com/carsonip/Penguin-Subtitle-Player.git#commit=$_commit"
  15         'git+https://gitlab.freedesktop.org/uchardet/uchardet.git')
  16 sha256sums=('SKIP'
  17             'SKIP')
  18
  19 pkgver() {
  20   cd Penguin-Subtitle-Player
  21   git describe --tags | sed 's/^v//;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd Penguin-Subtitle-Player
  26   git submodule init
  27   git submodule set-url src/uchardet "$srcdir/uchardet"
  28   git -c protocol.file.allow=always submodule update
  29
  30   # Add better integration for Linux
  31   git cherry-pick -n 96ec9e4d7b1adf6de3b3ed71b6c57c8cb362fcae
  32 }
  33
  34 build() {
  35   cd Penguin-Subtitle-Player
  36   qmake-qt5 PREFIX=/usr PenguinSubtitlePlayer.pro
  37   make
  38 }
  39
  40 package() {
  41   cd Penguin-Subtitle-Player
  42   make INSTALL_ROOT="$pkgdir" install
  43 }