python-debian/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Justin Vreeland <vreeland.justin@gmail.com>
   3 # Contributor: Mike Javorski (javmorin) <mike.javorski gmail com>
   4 # Contributor: Johannes Dewender   arch at JonnyJD dot net
   5
   6 pkgname=python-debian
   7 pkgver=0.1.49
   8 pkgrel=2
   9 pkgdesc='Python module to work with Debian-related data formats'
  10 arch=('any')
  11 url='https://salsa.debian.org/python-debian-team/python-debian'
  12 license=('GPL')
  13 depends=(
  14   'python'
  15   'python-chardet'
  16   'python-six'
  17 )
  18 makedepends=(
  19   'git'
  20   'python-build'
  21   'python-installer'
  22   'python-wheel'
  23   'python-setuptools'
  24 )
  25 checkdepends=('python-pytest')
  26 _commit='23f50416fce5ee7f1590b3ad1a49ec52e2e986d7'
  27 source=("$pkgname::git+$url.git#commit=$_commit")
  28 b2sums=('SKIP')
  29
  30 pkgver() {
  31   cd "$pkgname"
  32
  33   git describe --tags
  34 }
  35
  36 build() {
  37   cd "$pkgname"
  38
  39   python -m build --wheel --no-isolation
  40 }
  41
  42 check() {
  43   cd "$pkgname"
  44
  45   pytest -v
  46 }
  47
  48 package() {
  49   cd "$pkgname"
  50
  51   python -m installer --destdir="$pkgdir" dist/*.whl
  52 }