python-dict2css/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-dict2css
   4 pkgver=0.3.0
   5 pkgrel=1
   6 pkgdesc='A μ-library for constructing cascading style sheets from Python dictionaries'
   7 arch=('any')
   8 url='https://github.com/sphinx-toolbox/dict2css'
   9 license=('MIT')
  10 depends=(
  11   'python'
  12   'python-css-parser'
  13   'python-domdf-python-tools'
  14 )
  15 makedepends=(
  16   'git'
  17   'python-build'
  18   'python-installer'
  19   'python-whey'
  20 )
  21 _commit='fe95ef7433306258a58b6a91b1e777c6c3628a1c'
  22 source=("$pkgname::git+$url#commit=$_commit")
  23 b2sums=('SKIP')
  24
  25 pkgver() {
  26   cd "$pkgname"
  27
  28   git describe --tags | sed 's/^v//'
  29 }
  30
  31 build() {
  32   cd "$pkgname"
  33
  34   python -m build --wheel --no-isolation
  35 }
  36
  37 package() {
  38   cd "$pkgname"
  39
  40   python -m installer --destdir="$pkgdir" dist/*.whl
  41
  42   # license
  43   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  44 }