python-scipy/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Thomas Dziedzic < gostrc at gmail >
   3 # Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
   4 # Contributor: Ray Rashif <schiv@archlinux.org>
   5 # Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
   6 # Contributor: Bodor Dávid Gábor <david.gabor.bodor@gmail.com>
   7 # Contributor: Andrzej Giniewicz <gginiu@gmail.com>
   8
   9 _name=scipy
  10 pkgname=python-scipy
  11 pkgver=1.10.1
  12 pkgrel=3
  13 pkgdesc='Open-source software for mathematics, science, and engineering'
  14 arch=(x86_64)
  15 url='https://www.scipy.org/'
  16 license=(BSD)
  17 depends=(python-numpy python-pooch)
  18 provides=(scipy)
  19 makedepends=(gcc-fortran cython python-pythran pybind11 meson-python python-build python-installer)
  20 checkdepends=(python-pytest)
  21 optdepends=('python-pillow: for image saving module')
  22 source=(https://pypi.python.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz)
  23 sha256sums=('2cf9dfb80a7b4589ba4c40ce7588986d6d5cebc5457cad2c2880f6bc2d42f3a5')
  24
  25 build() {
  26   cd $_name-$pkgver
  27   python -m build --wheel --no-isolation --skip-dependency-check \
  28     -C setup-args=-Dblas=blas \
  29     -C setup-args=-Dlapack=lapack
  30 }
  31
  32 check() {
  33   cd $_name-$pkgver
  34   python -m venv --system-site-packages test-env
  35   test-env/bin/python -m installer dist/*.whl
  36   cd test-env
  37   bin/python -c "from scipy import test; test('full')"
  38 }
  39
  40 package() {
  41   cd $_name-$pkgver
  42   python -m installer --destdir="$pkgdir" dist/*.whl
  43   install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
  44 }