xine-lib/repos/community-x86_64/PKGBUILD

   1 # Maintainer : Daniel Bermond <dbermond@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=xine-lib
   5 pkgver=1.2.13
   6 pkgrel=3
   7 pkgdesc='Multimedia playback engine'
   8 arch=('x86_64')
   9 url='https://www.xine-project.org'
  10 license=('GPL' 'LGPL')
  11 depends=('ffmpeg' 'libjpeg-turbo' 'libmodplug' 'libnsl' 'libpng' 'libx11' 'libxcb'
  12          'libxext' 'libxinerama' 'libxv' 'libxvmc' 'zlib')
  13 optdepends=('libdvdnav: for dvd plugin'
  14             'libdvdread: for spu and dxr3 plugins'
  15             'vcdimager: for vcd plugin'
  16             'glu: for opengl and vaapi plugins'
  17             'sdl: for sdl plugin'
  18             'wayland: for egl_wl plugin'
  19             'aalib: for aalib plugin'
  20             'a52dec: for a52 plugin'
  21             'faad2: for faad plugin'
  22             'flac: for flac plugin'
  23             'libdca: for dts (dca) plugin'
  24             'libmad: for mad (mp3) plugin'
  25             'libmpcdec: for mpc (musepack) plugin'
  26             'libmodplug: for modplug plugin'
  27             'wavpack: for wavpack plugin'
  28             'gdk-pixbuf2: for gdk_pixbuf plugin'
  29             'imagemagick: for imagemagick plugin'
  30             'libcaca: for caca plugin'
  31             'libmng: for mng plugin'
  32             'libnfs: for nfs plugin'
  33             'libssh2: for ssh plugin'
  34             'smbclient: for samba plugin')
  35 makedepends=('mesa' 'libdvdnav' 'libdvdread' 'vcdimager' 'glu' 'sdl'
  36              'wayland' 'aalib' 'a52dec' 'faad2' 'flac' 'libdca' 'libmad'
  37              'libmpcdec' 'wavpack' 'gdk-pixbuf2' 'imagemagick' 'libcaca'
  38              'libmng' 'libnfs' 'smbclient')
  39 source=("https://downloads.sourceforge.net/project/xine/xine-lib/${pkgver}/xine-lib-${pkgver}.tar.xz")
  40 sha256sums=('3def43d3c0597f0f23cbf73e9d4b1dcd328852f2100fcff89fe925ad7cdd0251')
  41
  42 build() {
  43     cd "${pkgname}.${pkgver}"
  44     ./configure \
  45         --prefix='/usr' \
  46         --enable-antialiasing \
  47         --with-external-dvdnav \
  48         --with-wavpack
  49     sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  50     make
  51 }
  52
  53 package() {
  54     make -C "${pkgname}.${pkgver}" DESTDIR="$pkgdir" install
  55 }