cl-bordeaux-threads/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Dacoda Strack <dacoda.strack@gmail.com>
   3
   4 pkgname=cl-bordeaux-threads
   5 _pkgname="${pkgname#cl-}"
   6 pkgver=0.8.8
   7 pkgrel=6
   8 pkgdesc='Portable shared-state concurrency for Common Lisp'
   9 arch=('any')
  10 url='https://sionescu.github.io/bordeaux-threads/'
  11 license=('MIT')
  12 depends=(
  13   'common-lisp'
  14   'cl-asdf'
  15   'cl-alexandria'
  16   'cl-global-vars'
  17   'cl-trivial-features'
  18   'cl-trivial-garbage'
  19 )
  20 makedepends=('git')
  21 checkdepends=('sbcl' 'cl-fiveam')
  22 _commit='076fe2380abbc59b06e495dc7a35aea8eb26ba3b'
  23 source=(
  24   "$pkgname::git+https://github.com/sionescu/bordeaux-threads#commit=$_commit"
  25   'run-tests.lisp'
  26 )
  27 b2sums=('SKIP'
  28         '91273084a1ebd68bdafc7ad4904d232f07046de74684575813b25eaa145eb8b7d1c6e0a2f0a114376cbe6cc30bd59f88cffdea007d0f71d36c29288fa70f733f')
  29
  30 pkgver() {
  31   cd "$pkgname"
  32
  33   git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
  34 }
  35
  36 check() {
  37   cd "$pkgname"
  38
  39   sbcl --script ../run-tests.lisp
  40 }
  41
  42 package() {
  43   cd "$pkgname"
  44
  45   # library
  46   install -vd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  47   cp -vr src test version.sexp "$_pkgname.asd" "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  48
  49   # documentation
  50   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README site/*
  51
  52   # license
  53   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  54 }