gnome-bluetooth/repos/community-x86_64/PKGBUILD

   1 # Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Roman Kyrylych <roman@archlinux.org>
   4
   5 pkgname=gnome-bluetooth
   6 pkgver=3.34.5
   7 pkgrel=4
   8 pkgdesc="GNOME Bluetooth Subsystem (legacy)"
   9 url="https://wiki.gnome.org/Projects/GnomeBluetooth"
  10 arch=(x86_64)
  11 license=(GPL LGPL)
  12 depends=(gtk3 libnotify bluez libcanberra systemd pulseaudio-bluetooth)
  13 makedepends=(gobject-introspection gtk-doc docbook-xsl git meson)
  14 checkdepends=(python-dbusmock)
  15 provides=(libgnome-bluetooth.so)
  16 options=(debug)
  17 _commit=736eadbfb693d9594371470ad83370d327df6f74  # tags/3.34.5^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gnome-bluetooth.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd gnome-bluetooth
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd gnome-bluetooth
  28
  29   # Remove bluetooth-sendto, shipped in gnome-bluetooth-3.0
  30   sed -i "/'sendto'/d" meson.build
  31 }
  32
  33 build() {
  34   arch-meson gnome-bluetooth build -D gtk_doc=true -D icon_update=false
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   meson test -C build --print-errorlogs
  40 }
  41
  42 package() {
  43   meson install -C build --destdir "$pkgdir"
  44 }
  45
  46 # vim:set sw=2 et: