libmesode/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgbase=libmesode
   4 pkgname=('libmesode' 'libmesode-doc')
   5 pkgver=0.10.1
   6 pkgrel=2
   7 pkgdesc='Simple, lightweight C library for writing prifanity XMPP client'
   8 url='https://github.com/boothj5/libmesode'
   9 arch=('x86_64')
  10 license=('GPL3' 'MIT')
  11 depends=('glibc' 'openssl' 'expat')
  12 makedepends=('doxygen')
  13 checkdepends=('check')
  14 source=(https://github.com/boothj5/libmesode/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('00890ac903ed367872903242116527f229255bcc8988f87005b12a40a903d3b6133dff26229387c49de1ba6d911707adfc73a8a662864843899322c90e10dba7')
  16 b2sums=('485ee7e431befadcee34a7c8535818f692d35f0b619784c95d19b9ab19b7b0fc25e64bdb0f50a89a2709386304b3bae724a3e66f1622bcb8cc2b290bed32fae5')
  17
  18 prepare() {
  19   cd ${pkgbase}-${pkgver}
  20   ./bootstrap.sh
  21 }
  22
  23 build() {
  24   cd ${pkgbase}-${pkgver}
  25   ./configure --prefix=/usr
  26   make
  27   doxygen
  28 }
  29
  30 check() {
  31   make -C ${pkgbase}-${pkgver} check
  32 }
  33
  34 package_libmesode() {
  35   provides=('libmesode.so')
  36   depends+=('libexpat.so')
  37   cd ${pkgbase}-${pkgver}
  38   make DESTDIR="${pkgdir}" install
  39   install -Dm 644 MIT-LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40 }
  41
  42 package_libmesode-doc() {
  43   pkgdesc+=' (documentation and samples)'
  44   depends=()
  45   options=('!strip')
  46   optdepends=('libmesode')
  47   cd ${pkgbase}-${pkgver}
  48   install -Dm 644 docs/html/* -t "${pkgdir}/usr/share/doc/${pkgname}/html"
  49   install -Dm 644 examples/{README.md,*.c} -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
  50   install -Dm 644 MIT-LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  51 }
  52
  53 # vim: ts=2 sw=2 et: