nbd/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: Gerhard Brauer <gerbra@archlinux.de>
   5
   6 pkgname=nbd
   7 pkgver=3.25
   8 pkgrel=1
   9 pkgdesc='tools for network block devices, allowing you to use remote block devices over TCP/IP'
  10 arch=('x86_64')
  11 url='https://github.com/NetworkBlockDevice/nbd/'
  12 license=('GPL')
  13 depends=('glib2' 'gnutls' 'libnl')
  14 backup=('etc/nbd-server/config')
  15 source=("https://github.com/NetworkBlockDevice/${pkgname}/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.xz"
  16         'config'
  17         'nbd.service'
  18         'sysusers_nbd.conf')
  19 sha256sums=('f5c8fd0fcb57b1c926594d0e57f356432ee08678bef1d40d088f0830f0cbdd0a'
  20             'ee2e9fbbeb8a8b9b71d16b6f32eb41788f6def9d00cc4a47897ed3cb97cdde7c'
  21             '1b1add55d82d7623eabf7ff3dfec15c1fbe3c340fa74160df3d60e91eb1c71ba'
  22             '3fd98fe87d0b31b82126dc669f00355865f58fae81af3fccbc0d06504baef6cd')
  23 build() {
  24   cd "${srcdir}/${pkgname}-${pkgver}"
  25
  26   ./configure \
  27     --prefix=/usr \
  28     --sbindir=/usr/bin \
  29     --sysconfdir=/etc \
  30     --enable-syslog
  31
  32   make
  33 }
  34
  35 # checks still fail...
  36 #check() {
  37 #  cd "${srcdir}/${pkgname}-${pkgver}"
  38 #
  39 #  make check
  40 #}
  41
  42 package() {
  43   cd "${srcdir}/${pkgname}-${pkgver}"
  44
  45   make DESTDIR="${pkgdir}" install
  46   install -D -m0644 systemd/nbd@.service "${pkgdir}"/usr/lib/systemd/system/nbd@.service
  47
  48   install -D -m0644 "${srcdir}"/config "${pkgdir}"/etc/nbd-server/config
  49   install -D -m0644 "${srcdir}"/nbd.service "${pkgdir}"/usr/lib/systemd/system/nbd.service
  50   install -D -m0644 "${srcdir}"/sysusers_nbd.conf "${pkgdir}"/usr/lib/sysusers.d/nbd.conf
  51
  52   install -D -m0644 doc/README "${pkgdir}"/usr/share/doc/nbd/README
  53 }