pyenv/repos/community-any/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 pkgname=pyenv
   4 pkgver=2.3.17
   5 pkgrel=3
   6 pkgdesc="Easily switch between multiple versions of Python"
   7 arch=(any)
   8 url="https://github.com/pyenv/pyenv"
   9 license=(MIT)
  10 depends=(bash)
  11 optdepends=('git: installing development versions')
  12 source=($url/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)
  13 sha512sums=('282f4b8de6e230bb959b86f6c791c6478fef23ad85148ddb00b92fa2ab1072c59f0982b940dfc572a274cd50d4430c157059c11b55b789b5adc5483d65d67465')
  14 b2sums=('d00f6a1c43e928a21e2973e5dfec393518545895be308eea7421b92084d59ef7d86662e0b875d35dbb1494585fdfda401369bc8a037c2666986a8d22e2f3a2d6')
  15
  16 package() {
  17   cd $pkgname-$pkgver
  18   # application
  19   install -vDm 755 libexec/* -t "$pkgdir/usr/share/$pkgname/libexec"
  20   install -vdm 755 "$pkgdir/usr/bin"
  21   ln -sv /usr/share/$pkgname/libexec/$pkgname "$pkgdir/usr/bin/$pkgname"
  22   # application hooks
  23   install -vDm 755 pyenv.d/exec/pip-rehash/* -t "$pkgdir/usr/share/$pkgname/pyenv.d/exec/pip-rehash/"
  24   install -vDm 644 pyenv.d/exec/*.bash -t "$pkgdir/usr/share/$pkgname/pyenv.d/exec/"
  25   install -vDm 644 pyenv.d/install/*.bash -t "$pkgdir/usr/share/$pkgname/pyenv.d/install/"
  26   install -vDm 644 pyenv.d/rehash/*.bash -t "$pkgdir/usr/share/$pkgname/pyenv.d/rehash"
  27   install -vDm 644 pyenv.d/rehash/conda.d/* -t "$pkgdir/usr/share/$pkgname/pyenv.d/rehash/conda.d"
  28   install -vDm 644 pyenv.d/rehash/source.d/* -t "$pkgdir/usr/share/$pkgname/pyenv.d/rehash/source.d"
  29   # plugin
  30   install -vDm 755 plugins/python-build/bin/* -t "$pkgdir/usr/share/$pkgname/plugins/python-build/bin"
  31   for bin in {${pkgname}-{install,uninstall},python-build}; do
  32     ln -sv /usr/share/$pkgname/plugins/python-build/bin/$bin "$pkgdir/usr/bin/$bin"
  33   done
  34   cp -av plugins/python-build/share "$pkgdir/usr/share/$pkgname/plugins/python-build"
  35   # licenses
  36   install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  37   install -vDm 644 plugins/python-build/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE.python-build"
  38   # shell completion
  39   install -vDm 644 completions/*.fish -t "$pkgdir/usr/share/fish/vendor_completions.d/"
  40   install -vDm 644 completions/$pkgname.bash "$pkgdir/usr/share/bash-completion/completions/$pkgname"
  41   install -vDm 644 completions/$pkgname.zsh "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
  42   # man page
  43   install -vDm 644 man/man1/*.1 -t "$pkgdir/usr/share/man/man1/"
  44   # docs
  45   install -vDm 644 {CHANGELOG,COMMANDS,README}.md -t "$pkgdir/usr/share/doc/$pkgname"
  46   install -vDm 644 plugins/python-build/README.md "$pkgdir/usr/share/doc/$pkgname/README-python-build.md"
  47 }