python-aiohttp-oauthlib/repos/community-any/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Contributor: Hugo Osvaldo Barrera <hugo@barrera.io>
   3
   4 _name=aiohttp-oauthlib
   5 pkgname=python-aiohttp-oauthlib
   6 pkgver=0.1.0
   7 pkgrel=3
   8 pkgdesc='oauthlib for aiohttp clients'
   9 arch=('any')
  10 url=https://git.sr.ht/~whynothugo/aiohttp-oauthlib
  11 license=('ISC')
  12 depends=('python-aiohttp' 'python-oauthlib')
  13 makedepends=('python-build' 'python-installer' 'python-setuptools-scm'
  14              'python-wheel')
  15 source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
  16 sha256sums=('893cd1a59ddd0c2e4e980e3a544f9710b7c4ffb9e27b4cd038b51fe1d70393b7')
  17 b2sums=('2925aeab72f7d38bb819646cf232278d93adb0a0375bc97fd6cfc133cbafc5e5fa87bfcfc8dd9056fe84ab4d3b5af3a57fbc0441b3c9f521ff7ffb6bb2598f3a')
  18
  19 build() {
  20   cd $_name-$pkgver
  21   python -m build --wheel --skip-dependency-check --no-isolation
  22 }
  23
  24 package() {
  25   cd $_name-$pkgver
  26   python -m installer --destdir="$pkgdir" dist/*.whl
  27
  28   # Symlink license file
  29   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  30   install -d "$pkgdir"/usr/share/licenses/$pkgname
  31   ln -s "$site_packages"/aiohttp_oauthlib-$pkgver.dist-info/LICENCE \
  32     "$pkgdir"/usr/share/licenses/$pkgname/LICENCE
  33 }