python-daemon/trunk/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Anatol Pomozov
   3 # Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
   4
   5 pkgname=python-daemon
   6 pkgver=2.3.0
   7 pkgrel=5
   8 pkgdesc='Library to implement a well-behaved Unix daemon process'
   9 arch=('any')
  10 url='https://pypi.python.org/pypi/python-daemon'
  11 license=('Apache')
  12 depends=('python' 'python-lockfile' 'python-setuptools')
  13 makedepends=('python-build' 'python-docutils' 'python-installer' 'python-wheel')
  14 checkdepends=('python-testscenarios' 'python-testtools')
  15 source=(https://files.pythonhosted.org/packages/source/p/$pkgname/$pkgname-$pkgver.tar.gz
  16         testtools-2.5.0.patch
  17         python310.patch)
  18 sha256sums=('bda993f1623b1197699716d68d983bb580043cf2b8a66a01274d9b8297b0aeaf'
  19             '7f8dfbe9e01edcb19ebede5580d448a995b721ee3b56ca1d353f58c36416c980'
  20             '1777e34936ed5d45001e9994f563fdf8c9e2045b667223f1eebf896031627ddc')
  21 b2sums=('6e7fa082a513827283f46044347dfd445633db0d1781a33aa1bc5b14c340da784310ae6bd07d6cf3673cd05cb14a9d090ab51857d26cca52d09bc8c3b195360f'
  22         'f794167aca806f608846e610b12a310f3e5a3ad9b426ab0b9069c92a552ea8817404f6ebfd6878257df6d346432c377471b377794948c3e341b40c296ab9dacb'
  23         'ffdf203815713a346ed0e35048aa8da886966625e1698b5362447e4733e68034efb078c150d698c7a253931aec930162f722e96ccaaa3fa84b2be0a8fee82341')
  24
  25 prepare() {
  26   cd $pkgname-$pkgver
  27   patch -Np1 -i ../testtools-2.5.0.patch
  28   patch -Np1 -i ../python310.patch
  29
  30   # NOTE: twine is *not* required for building this package
  31   sed -e '/twine/d' -i setup.py
  32 }
  33
  34 build() {
  35   cd $pkgname-$pkgver
  36   python -m build --wheel --no-isolation
  37 }
  38
  39 check() {
  40   cd $pkgname-$pkgver
  41   python -m unittest discover -v
  42 }
  43
  44 package_python-daemon() {
  45   cd $pkgname-$pkgver
  46   python -m installer --destdir="$pkgdir" dist/*.whl
  47
  48   install -Dm644 LICENSE.ASF-2 "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE.ASF-2
  49   install -Dm644 LICENSE.GPL-3 "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE.GPL-3
  50 }