python-edalize/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 _pkgname=edalize
   4 pkgname=python-$_pkgname
   5 pkgver=0.5.0
   6 pkgrel=2
   7 pkgdesc='An abstraction library for interfacing EDA tools'
   8 arch=('any')
   9 url='https://github.com/olofk/edalize'
  10 license=('BSD')
  11 depends=('python' 'python-jinja' 'python-pyparsing')
  12 makedepends=('python-setuptools-scm')
  13 checkdepends=('python-pytest' 'python-pandas' 'iverilog')
  14 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  15 sha512sums=('c0e4b21eb8ae43e2d1a54096ae4a82b36cdfd7ee66126978a2d0e148693b659309fca607098f37fd1425317f6161a09cc1eea1de99e0727bc8942fd5d6f76e7c')
  16
  17 export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
  18
  19 prepare() {
  20   cd $_pkgname-$pkgver
  21
  22   rm tests/test_spyglass.py
  23
  24   sed -i '/pytest/d' setup.py
  25 }
  26
  27 build() {
  28   cd $_pkgname-$pkgver
  29
  30   python setup.py build
  31 }
  32
  33 check() {
  34   cd $_pkgname-$pkgver
  35
  36   PYTHONPATH=. pytest
  37 }
  38
  39 package() {
  40   cd $_pkgname-$pkgver
  41
  42   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  43
  44   install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  45 }
  46
  47 # vim:set ts=2 sw=2 et: