python-latex2mathml/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-latex2mathml
   4 pkgver=3.75.3
   5 pkgrel=1
   6 pkgdesc="Pure Python library for LaTeX to MathML conversion"
   7 url="https://github.com/roniemartinez/latex2mathml"
   8 license=('MIT')
   9 arch=('any')
  10 depends=('python-setuptools')
  11 makedepends=('python-build' 'python-installer' 'python-poetry-core')
  12 checkdepends=('python-pytest' 'python-multidict' 'python-xmljson')
  13 source=("https://github.com/roniemartinez/latex2mathml/archive/$pkgver/$pkgname-$pkgver.tar.gz")
  14 sha512sums=('bf2d0e54f0d7640818cbfd27238a9fd9471ecbf591566b685d729d9596eca0574cbf43cc5c642947dc2f780e1990095ac7d814ccb31062a25b81b0ffea67c04e')
  15
  16 prepare() {
  17   cd latex2mathml-$pkgver
  18   sed -i '/--cov/d' pyproject.toml
  19 }
  20
  21 build() {
  22   cd latex2mathml-$pkgver
  23   python -m build -nw
  24 }
  25
  26 check() {
  27   cd latex2mathml-$pkgver
  28   pytest
  29 }
  30
  31 package() {
  32   cd latex2mathml-$pkgver
  33   python -m installer -d "$pkgdir" dist/*.whl
  34   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  35 }