python-libevdev/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 pkgname=python-libevdev
   4 pkgver=0.11
   5 pkgrel=2
   6 arch=('any')
   7 url='https://gitlab.freedesktop.org/libevdev/python-libevdev'
   8 license=('MIT')
   9 pkgdesc='Python wrapper for libevdev'
  10 depends=('python' 'libevdev')
  11 makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx_rtd_theme')
  12 checkdepends=('python-pytest' 'python-py' 'python-pluggy')
  13 source=("$url/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
  14 sha512sums=('224e2d18915f08d9f02e32845968e0e2eac531ad7f4efe5401de692cdb0980049f3cfd9cb869319e7526dbefd38144ab6e0b52ceba67ab371045ce60d21286da')
  15
  16 build() {
  17   cd $pkgname-$pkgver
  18
  19   python setup.py build
  20
  21   make doc
  22 }
  23
  24 check() {
  25   cd $pkgname-$pkgver
  26
  27   PYTHONPATH=. pytest test/*.py
  28 }
  29
  30 package() {
  31   cd $pkgname-$pkgver
  32
  33   python setup.py install --root "$pkgdir" --skip-build -O1
  34
  35   # Install documentation
  36   install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  37   cp -r -a --no-preserve=ownership doc/html "$pkgdir"/usr/share/doc/$pkgname
  38   install -D -m644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39   rm -rf "$pkgdir"/usr/share/doc/$pkgname/html/.doctrees
  40 }