python-more-itertools/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Kyle Keen <keenerd@gmail.com>
   3 # Contributor: Germán Osella Massa <gosella@gmail.com>
   4
   5 pkgname=python-more-itertools
   6 pkgver=9.1.1
   7 pkgrel=4
   8 pkgdesc='More routines for operating on iterables, beyond itertools'
   9 arch=('any')
  10 url='https://github.com/more-itertools/more-itertools'
  11 license=('MIT')
  12 depends=('python')
  13 makedepends=(
  14   'git'
  15   'python-build'
  16   'python-installer'
  17   'python-wheel'
  18   'python-flit-core'
  19 )
  20 _commit='89d58c2ec089f3df54ed6cc9279949b8e2bbcd29'
  21 source=("$pkgname::git+$url#commit=$_commit")
  22 b2sums=('SKIP')
  23
  24 pkgver() {
  25   cd "$pkgname"
  26
  27   git describe --tags | sed 's/^v//'
  28 }
  29
  30 build() {
  31   cd "$pkgname"
  32
  33   python -m build --wheel --no-isolation
  34 }
  35
  36 check() {
  37   cd "$pkgname"
  38
  39   python -m unittest
  40 }
  41
  42 package() {
  43   cd "$pkgname"
  44
  45   python -m installer --destdir="$pkgdir" dist/*.whl
  46
  47   # license
  48   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  49 }
  50
  51 # vim:set ts=2 sw=2 et: