ruby-bcrypt_pbkdf/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Tim Meusel <tim@bastelfreak.de>
   2
   3 _gemname='bcrypt_pbkdf'
   4 pkgname="ruby-${_gemname}"
   5 pkgver=1.1.0
   6 pkgrel=3
   7 pkgdesc="OpenBSD's bcrypt_pdkfd (a variant of PBKDF2 with bcrypt-based PRF)"
   8 arch=('x86_64')
   9 url='https://github.com/net-ssh/bcrypt_pbkdf-ruby'
  10 license=('MIT')
  11 depends=('ruby')
  12 makedepends=('ruby-rake' 'ruby-bundler' 'ruby-rdoc' 'ruby-rake-compiler')
  13 checkdepends=('ruby-minitest')
  14 options=('!emptydirs')
  15 source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
  16 sha512sums=('d7a21ff439b2d023597f1cd45e16b9072f4747fa9498dbcb1920a615dcd09ac020ebbe2a99275042d7bf87a4db207b8329a3c7ef2a95405ad0491d0b8afb6d02')
  17 provides=('bcrypt_pbkdf_ext.so')
  18 prepare() {
  19   cd "${srcdir}/${_gemname}-ruby-${pkgver}"
  20
  21   sed -E 's|~>|>=|g' --in-place "${_gemname}.gemspec"
  22   sed --in-place 's|git ls-files|find|' "${_gemname}.gemspec"
  23   sed --in-place '/bundler/d' Rakefile
  24   sed --in-place '/rake-compiler-dock/d' bcrypt_pbkdf.gemspec
  25   sed --in-place '/has_rdoc/d' bcrypt_pbkdf.gemspec
  26 }
  27
  28 build() {
  29   cd "${srcdir}/${_gemname}-ruby-${pkgver}"
  30   rake compile
  31   rake gem
  32 }
  33
  34 check() {
  35   cd "${srcdir}/${_gemname}-ruby-${pkgver}"
  36   rake test
  37 }
  38
  39 package() {
  40   cd "${srcdir}/${_gemname}-ruby-${pkgver}"
  41   local _gemdir="$(gem env gemdir)"
  42   gem install --ignore-dependencies --no-user-install --install-dir "${pkgdir}${_gemdir}" --bindir "${pkgdir}/usr/bin" "pkg/${_gemname}-${pkgver}.gem"
  43   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  44   install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  45   rm -rf ${pkgdir}/${_gemdir}/gems/${_gemname}-${pkgver}/{ext,tmp}
  46   rm -rf "${pkgdir}/${_gemdir}/cache"
  47   rm -rf ${pkgdir}/${_gemdir}/extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
  48   rm -rf "${pkgdir}/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext"
  49 }
  50
  51 # vim: ts=2 sw=2 et: