springlobby/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: DuGi <dugi@irc.pl>
   3
   4 pkgname=springlobby
   5 pkgver=0.274
   6 pkgrel=1
   7 pkgdesc="A free cross-platform lobby client for the Spring RTS project"
   8 arch=('x86_64')
   9 url="https://springlobby.springrts.com/"
  10 license=('GPL2')
  11 depends=('hicolor-icon-theme' 'wxwidgets-gtk3' 'curl' 'jsoncpp' 'alure'
  12          'minizip' 'libsm')
  13 makedepends=('boost' 'cmake' 'ninja')
  14 source=("https://springlobby.springrts.com/dl/stable/springlobby-${pkgver}.tar.bz2")
  15 sha512sums=('eef1a58ffbcf4c8aa3c4bf2c555775412649f5e8a589a47d004c605576570c2e441f35ea20a22bf618a2be6b3b104dbbec1f45d6cd221d3537eee7b0c4c754a0')
  16
  17 prepare() {
  18   cd $pkgname-$pkgver
  19   # remove bundled libraries
  20   rm -r src/downloader/lib/src/lib/jsoncpp
  21   rm -r src/downloader/lib/src/lib/minizip
  22 }
  23
  24 build() {
  25   cd $pkgname-$pkgver
  26
  27   cmake \
  28     -GNinja \
  29     -Bbuild \
  30     -DCMAKE_INSTALL_PREFIX=/usr \
  31     -DPRD_JSONCPP_INTERNAL=OFF
  32   ninja -C build
  33 }
  34
  35 package() {
  36   cd $pkgname-$pkgver
  37
  38   DESTDIR="$pkgdir" ninja -C build install
  39 }
  40
  41 # vim: sw=2:ts=2 et: