vim-jedi/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3 # Contributor: Danilo Bargen <gezuru@gmail.com>
   4
   5 pkgname=vim-jedi
   6 _reponame=jedi-vim
   7 pkgver=0.11.1
   8 pkgrel=2
   9 pkgdesc='Vim plugin for jedi, an awesome Python autocompletion'
  10 url='https://github.com/davidhalter/jedi-vim'
  11 arch=('any')
  12 license=('MIT')
  13 depends=('vim' 'python-jedi' 'python')
  14 optdepends=('vim-supertab: tab completion'
  15             'python2-jedi: Python 2 support')
  16 checkdepends=('python-pytest')
  17 groups=('vim-plugins')
  18 options=('!emptydirs')
  19 source=(https://github.com/davidhalter/${_reponame}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  20 sha256sums=('b20e7ffadf73c929e250ea9de6d4752b4bb3fbcd58c2a82b3677d4fd4d1e3713')
  21 b2sums=('7a069188c6c2886d483ecf98e970fe84be9edf88a4a666d6766c663efdd9febb39c6af058a2ef9e42f4c878f964b8b1a645c31f31b16e1904287e148e9c4f916')
  22
  23 check() {
  24   cd ${_reponame}-${pkgver}
  25   py.test
  26 }
  27
  28 package() {
  29   cd ${_reponame}-${pkgver}
  30
  31   install -d "${pkgdir}/usr/share/vim/vimfiles"
  32   cp -dpr --no-preserve=ownership pythonx "${pkgdir}/usr/share/vim/vimfiles"
  33   cp -dpr --no-preserve=ownership doc "${pkgdir}/usr/share/vim/vimfiles/doc"
  34   cp -dpr --no-preserve=ownership after "${pkgdir}/usr/share/vim/vimfiles/after"
  35   cp -dpr --no-preserve=ownership autoload "${pkgdir}/usr/share/vim/vimfiles/autoload"
  36   cp -dpr --no-preserve=ownership ftplugin "${pkgdir}/usr/share/vim/vimfiles/ftplugin"
  37   cp -dpr --no-preserve=ownership plugin "${pkgdir}/usr/share/vim/vimfiles/plugin"
  38
  39   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40 }