xaos/trunk/PKGBUILD

   1 # Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=xaos
   5 pkgver=4.2.1
   6 pkgrel=3
   7 pkgdesc='Interactive fractal zoomer'
   8 arch=(x86_64)
   9 url='https://xaos-project.github.io/'
  10 license=(GPL2)
  11 makedepends=(gendesk git qt5-tools)
  12 depends=(qt5-base)
  13 source=("git+https://github.com/xaos-project/XaoS#commit=632a48b088326a916e7c6f8fdb4a549ddfcbc7c0") # tag: release-4.2.1
  14 sha256sums=('SKIP')
  15
  16 prepare() {
  17   # Add missing include
  18   sed -i '30i#include <cstdlib>' XaoS/src/util/timers.cpp
  19
  20   # Desktop shortcut
  21   gendesk -f -n \
  22     --pkgname=XaoS \
  23     --pkgdesc="$pkgdesc" \
  24     --exec=xaos \
  25     --icon=xaos \
  26     --categories='Application;Graphics'
  27 }
  28
  29 build() {
  30   cd XaoS
  31   export DEFINES='USE_OPENGL USE_FLOAT128'
  32   qmake && make
  33 }
  34
  35 package() {
  36   cd XaoS
  37
  38   # Executable
  39   install -Dm755 bin/xaos "$pkgdir/usr/bin/xaos"
  40
  41   # Tutorial and catalogs
  42   install -d "$pkgdir/usr/share/XaoS/"
  43   cp -r tutorial catalogs "$pkgdir/usr/share/XaoS"
  44
  45   # Examples
  46   install -d "$pkgdir/usr/share/XaoS/examples"
  47   find examples -name "*.xpf" -exec install -Dm644 -t "$pkgdir"/usr/share/XaoS/examples/ {} \;
  48
  49   # Desktop shortcut and icon
  50   install -Dm644 ../XaoS.desktop \
  51     "$pkgdir/usr/share/applications/$pkgname.desktop"
  52   install -Dm644 "src/ui/images/xaosbig.png" \
  53     "$pkgdir/usr/share/pixmaps/$pkgname.png"
  54
  55   # Man page
  56   install -Dm644 doc/xaos.6 "$pkgdir/usr/share/man/man6/xaos.6"
  57 }