adwaita-qt/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
   3 # Contributor: Victor Homic <aur (at) dothomic (dot) de>
   4 # Contributor: Iyán Méndez Veiga <me (at) iyanmv (dot) com>
   5 # Contributor: Aniket Pradhan <aniket17133 (at) iiitd (dot) ac (dot) in>
   6 # Contributor: Martin Briza <m (at) rtinbriza (dot) cz>
   7
   8 pkgbase=adwaita-qt
   9 pkgname=(adwaita-qt5 adwaita-qt6)
  10 pkgver=1.4.2
  11 pkgrel=1
  12 pkgdesc='A style to bend Qt applications to look like they belong into GNOME Shell'
  13 arch=(x86_64)
  14 url='https://github.com/FedoraQt/adwaita-qt'
  15 license=(GPL)
  16 makedepends=(cmake qt5-x11extras qt6-base)
  17 source=(https://github.com/FedoraQt/adwaita-qt/archive/$pkgver/$pkgname-$pkgver.tar.gz)
  18 sha256sums=('cd5fd71c46271d70c08ad44562e57c34e787d6a8650071db115910999a335ba8')
  19
  20 build() {
  21   cmake -B build-qt5 -S $pkgbase-$pkgver \
  22     -DCMAKE_INSTALL_PREFIX=/usr \
  23     -DUSE_QT6=OFF
  24   cmake --build build-qt5
  25
  26   cmake -B build-qt6 -S $pkgbase-$pkgver \
  27     -DCMAKE_INSTALL_PREFIX=/usr \
  28     -DUSE_QT6=ON
  29   cmake --build build-qt6
  30 }
  31
  32 package_adwaita-qt5() {
  33   pkgdesc='A style to bend Qt5 applications to look like they belong into GNOME Shell'
  34   depends=(qt5-x11extras)
  35   replaces=(adwaita-qt)
  36
  37   DESTDIR="$pkgdir" cmake --install build-qt5
  38 }
  39
  40 package_adwaita-qt6() {
  41   pkgdesc='A style to bend Qt6 applications to look like they belong into GNOME Shell'
  42   depends=(qt6-base)
  43
  44   DESTDIR="$pkgdir" cmake --install build-qt6
  45 }
  46