atftp/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Benjamin Bukowski <benjamin.bukowski@gmail.com>
   2 # Contributor: Johannes Löthberg <demizide@gmail.com>
   3
   4 pkgname=atftp
   5 pkgver=0.8.0
   6 pkgrel=3
   7 pkgdesc='Client/server implementation of the TFTP protocol that implements RFCs 1350, 2090, 2347, 2348, and 2349'
   8 arch=('x86_64')
   9 url='https://sourceforge.net/projects/atftp/'
  10 license=('GPL')
  11 depends=('pcre2' 'readline')
  12 backup=('etc/conf.d/atftpd')
  13 options=('debug' '!lto')
  14 source=("https://downloads.sf.net/sourceforge/atftp/atftp-${pkgver}.tar.gz"
  15         'atftpd.service'
  16         'atftpd.conf'
  17         'sysusers.conf'
  18         'tmpfiles.conf')
  19 sha256sums=('df2aa089c7670f9eab40e5598e5d2cb6a582dc5182926ea50b4d690e4e37f316'
  20             '74a030f0fb48e97470d59d767039e44d28cbd6c4722621207684220210b8fa65'
  21             '0b28125099ffdd6869c6fbcb3167e93ccd71a0c6e465b1b62c7dedf9f628dd4e'
  22             'e56f601bcdf0d64bf98813cd4a1be323541e33921c7d4f350168f62b56e66d11'
  23             '2096272445c736ba05529af628cc2d46d0236c8f1ecbd50bb1db6dc6c4a972c5')
  24
  25 prepare() {
  26   cd "atftp-${pkgver}/"
  27
  28   autoreconf -fi
  29 }
  30
  31 build() {
  32   cd "atftp-${pkgver}/"
  33
  34   ./configure \
  35     --prefix=/usr \
  36     --mandir=/usr/share/man \
  37     --sbindir=/usr/bin \
  38     --enable-libreadline \
  39     --disable-libwrap
  40   make
  41 }
  42
  43 package() {
  44   cd "atftp-${pkgver}/"
  45
  46   make DESTDIR="$pkgdir" install
  47
  48   install -D -m0644 ../atftpd.service "$pkgdir"/usr/lib/systemd/system/atftpd.service
  49   install -D -m0644 ../atftpd.conf "$pkgdir"/etc/conf.d/atftpd
  50   install -D -m0644 ../sysusers.conf "$pkgdir"/usr/lib/sysusers.d/atftp.conf
  51   install -D -m0644 ../tmpfiles.conf "$pkgdir"/usr/lib/tmpfiles.d/atftp.conf
  52
  53   # remove in.tftpd link as it conflicts with extra/tftp-hpa
  54   rm "${pkgdir}/usr/share/man/man8/in.tftpd.8"
  55   rm "${pkgdir}/usr/bin/in.tftpd"
  56 }