bibletime/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Maintainer: T.J. Townsend <blakkheim@archlinux.org>
   4 # Contributor: Alexander F Rødseth <xyproto@archlinux.org>
   5 # Contributor: SanskritFritz (gmail)
   6 # Contributor: Tobias T. <OldShatterhand at gmx-topmail dot de>
   7
   8 pkgname=bibletime
   9 _commit=48ccda7618ad7512ca481fc088dc53a9c692a5d6 # git rev-parse v$pkgver
  10 pkgver=3.0.3
  11 pkgrel=2
  12 pkgdesc='Bible study tool'
  13 arch=('x86_64')
  14 url='https://www.bibletime.info/'
  15 license=('GPL2')
  16 depends=('sword' 'clucene' 'qt5-webengine' 'qt5-svg')
  17 makedepends=('cmake' 'docbook-xsl' 'expac' 'fop' 'git' 'ninja' 'po4a' 'qt5-tools')
  18 source=("git+https://github.com/bibletime/bibletime.git?signed#tag=$_commit")
  19 sha256sums=('SKIP')
  20 validpgpkeys=('6C0462117260CA4934F7B3E049D76194699FD9A4') # Jaak Ristioja
  21
  22 build() {
  23   local _xsl_shared=/usr/share/xml/docbook/xsl-stylesheets-$(expac %v docbook-xsl | cut -d - -f 1)
  24   cmake -B build -G Ninja $pkgname \
  25     -DCMAKE_BUILD_TYPE=None \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DBT_DOCBOOK_XSL_HTML_CHUNK_XSL=$_xsl_shared/html/chunk.xsl \
  28     -DBUILD_HANDBOOK_PDF=OFF \
  29     -DBUILD_HOWTO_PDF=OFF \
  30     -Wno-dev
  31   ninja -C build
  32 }
  33
  34 package() {
  35   DESTDIR="$pkgdir" ninja -C build install
  36 }
  37
  38 # vim:set ts=2 sw=2 et: